实验4 8086标志寄存器及中断

本文主要是介绍实验4 8086标志寄存器及中断，对大家解决编程问题具有一定的参考价值，需要的程序猿们随着小编来一起学习吧！

实验任务1

task1.asm源码

assume cs:code, ds:data

data segment
    x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
    y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end  start

① line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

add si, 2
add di, 2

替换代码后，重新编译运行，结果出错，调试结果如下图

不能替换。理由：add指令会影响进位标志位CF，可能会影响adc指令运算结果，从而造成错误。

②在debug中调试，观察数据段中做128位加之前和加之后，数据段的值的变化。给出调试观察截图。

实验任务2

task2.asm源码:

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

运行调试截图：

① 汇编指令代码line11-18，实现的功能是？　　 从键盘循环读入单个字符存入偏移地址si指向空间，直到读入#停止，并跳转到next标号处。 ② 汇编指令代码line20-22，实现的功能是？　　 输出换行符（换行符的ASCII码值为0AH）。 ③ 汇编指令代码line24-30，实现的功能是？　　 循环打印数据段中si个字符。

实验任务3

task3.asm源码

assume cs:code, ds:data
data segment
        x dw 91, 792, 8536, 65521, 2021
        len equ $ - x
data ends

stack segment
        db 16 dup(0)
stack ends

code segment
start:
        mov ax, data
        mov ds, ax

        mov cx, 5
        mov si, offset x
s:      mov ax, ds:[si]
        call printNumber
        call printSpace
        inc si
        inc si
        loop s

        mov ah, 4ch
        int 21h

printNumber:
        mov bx, 0AH     
        mov dx, 0       
        mov di, 0
        push cx
s1:     div bx
        push dx         
        inc di
        mov dx, 0
        cmp ax, 0       
        je next
        jmp s1

next:   mov ah, 2
        mov cx, di

s2:     pop dx
        or dl, 30H      
        int 21h
        loop s2

        pop cx
        ret

printSpace:
        mov dl, ' '
        mov ah, 2
        int 21h
        ret

code ends
end start

运行测试结果：

实验任务4

task4.asm源码

assume cs:code,ds:data

data segment
    str db "assembly language, it's not difficult but tedious"
    len equ $ - str
data ends

code segment
start:
    mov ax, data
    mov ds, ax
    mov si, offset str
    mov cx, len
    call strupr;
    mov ax, 4c00h
    int 21h

strupr:
    mov al, [si]
    cmp al, 97
    jb s
    cmp al, 122
    ja s
    and al, 0dfh
    mov [si], al
  s:inc si
    loop strupr
    ret
code ends
end start

debug调试截图：

 

实验任务5

task5.asm源码

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:
    mov ah, 4ch
    int 21h
code ends
end star

程序运行截图：

 程序功能：

判断输入的字符是否为'7',是则输出yes，不是则输出no。

实验任务6

task6_1.asm源码

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42:
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
   nop
code ends
end start

task6_2.asm源码

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start

 通过此项实现任务，你对中断、软中断的理解？

当CPU内部有需要处理的事件发生时，将产生中断信息，从而引发中断过程；

汇编语言中的软中断类似于高级语言中的函数调用。

 

 

这篇关于实验4 8086标志寄存器及中断的文章就介绍到这儿，希望我们推荐的文章对大家有所帮助，也希望大家多多支持为之网！