本文主要是介绍Linux0.11源码学习（一），对大家解决编程问题具有一定的参考价值，需要的程序猿们随着小编来一起学习吧！

Linux0.11源码学习（一）

linux0.11源码学习笔记
参考资料：https://github.com/sunym1993/flash-linux0.11-talk
源码查看：https://elixir.bootlin.com/linux/latest/source

开始

电脑开机后，CPU初始化，固定的BIOS程序运行，将硬盘启动区的512字节的内容，复制到内存中的 0x7c00 的位置，并跳转到该位置，然后CPU就自此位置开始执行指令。

这部分需要存放的是操作系统开始的代码，这样操作系统才能正常运行。

这部分内容对应于源码的bootsect.s文件

/boot/bootsect.s

mov ax,#BOOTSEG ;#BOOTSET已定义，表示立即数 0x07c0， 
mov ds,ax

操作：

把 0x07c0 这个值复制到 ax 寄存器里，再将 ax 寄存器里的值复制到 ds 寄存器里。

解释：
寄存器知识回顾：

寄存器的英文全称或许能帮助记忆

ds 是 16 位的数据段寄存器，在内存寻址时作为段基址使用。

值得一提，x86 汇编中，某个地址由段基址和偏移地址构成，构成方法为：段基址左移4位+偏移地址。例如：[0x7c0:0x001] = [0x7c01]。通常情况下，段基址可以省略，因为默认是ds。

为什么要给ds赋值0x07c0？

因为上面提到，BIOS程序将硬盘启动区的512字节的内容，复制到内存中的 0x7c00 的位置。这样将基址确定，方便通过该基址访问内存数据。

至于为什么0x7c00到0x7dff有512个字节，我们可以计算一下0x7dff-0x7c00=0x1ff=511，一个地址数实际上对应一个字节（8bit），因此实际上应当是0x7c00到0x7e00才是512字节，因为上面那张图解是大佬的，我们就暂时忽略这个小细节吧。

mov ax,#INITSEG ;#INITSEG已定义，表示立即数 0x9000
mov es,ax
mov cx,#256 ;256为十进制数
sub si,si ;si源变址寄存器清零 等价于si = si - si 
sub di,di ;di目的变址寄存器
rep movw 

操作：

将内存地址 0x7c00 处开始往后的 512 字节的数据，原封不动复制到 0x90000 处。

解释：

rep 表示重复执行后面的指令，这里表示重复执行movw，即不断重复地复制一个字。

重复执行多少次? 取决于 cx 寄存器中的值，也就是 256 次。

从哪复制到哪？ 从 ds:si 处复制到 es:di 处。

一个字多大？ 16 位，也就是两个字节。

图解：

jmpi go,0x9000 
go:   
  mov ax,cs 
  mov ds,ax

操作：

指令运行跳转至特定位置

解释:

jmpi 是一个段间跳转指令，表示跳转到 0x9000:go 处执行。

go 就是一个标签，最终编译成机器码的时候会被翻译成一个值，这个值就是 go 这个标签在文件内的偏移地址。

图解：

go: mov ax,cs
    mov ds,ax
    mov es,ax
    mov ss,ax
    mov sp,#0xFF00

含义：

把 cs 寄存器的值分别复制给 ds、es 和 ss 寄存器，然后又把 0xFF00 给了 sp 寄存器。

解释:

cs 寄存器表示代码段寄存器。CPU 当前正在执行的代码在内存中的位置，就是由 cs:ip 这组寄存器配合指向的，其中 cs 是基址，ip 是偏移地址。

执行指令jmpi go,0x9000后，cs 寄存器里的值就是 0x9000，ip 寄存器里的值是 go 这个标签的偏移地址。因此 ds、es 和 ss 寄存器的值为 0x9000 。

ss 为栈段寄存器，后面要配合栈基址寄存器 sp 来表示此时的栈顶地址。而此时 sp 寄存器被赋值为了 0xFF00 了，所以目前的栈顶地址就是 ss:sp 所指向的地址 0x9FF00 处。

栈是向下发展的，这个栈顶地址 0x9FF00 要远远大于此时代码所在的位置 0x90000，所以栈向下发展就很难撞见代码所在的位置，也就比较安全。

load_setup:
	mov	dx,#0x0000		! drive 0, head 0
	mov	cx,#0x0002		! sector 2, track 0
	mov	bx,#0x0200		! address = 512, in INITSEG
	mov	ax,#0x0200+SETUPLEN	! service 2, nr of sectors, knowned:SETUPLEN=4
	int	0x13			! read it
	jnc	ok_load_setup		! ok - continue
	mov	dx,#0x0000
	mov	ax,#0x0000		! reset the diskette
	int	0x13
	j	load_setup

ok_load_setup:

含义：
调用 0x13 号中断程序 ，0x13 号中断的处理程序是 BIOS 提前给我们写好的，是读取磁盘的相关功能的函数。
具体作用是，将硬盘的第 2 个扇区开始，把数据加载到内存 0x90200 处，共加载 4 个扇区。

解释:
为dx，cx，bx，ax寄存器赋值，作为 0x13 号中断程序的参数；

int 是汇编指令，表示发起中断。

图解：

接上文

ok_load_setup:

! Get disk drive parameters, specifically nr of sectors/track

   mov	dl,#0x00
   mov	ax,#0x0800		! AH=8 is get drive parameters
   int	0x13
   mov	ch,#0x00
   seg cs
   mov	sectors,cx
   mov	ax,#INITSEG   ！INITSEG  = 0x9000
   mov	es,ax

! Print some inane message

   mov	ah,#0x03		! read cursor pos
   xor	bh,bh
   int	0x10
   
   mov	cx,#24
   mov	bx,#0x0007		! page 0, attribute 7 (normal)
   mov	bp,#msg1	        ! msg1是个标号，在该文件的尾部定义，等价于一个立即数
   mov	ax,#0x1301		! write string, move cursor
   int	0x10



! ok, we've written the message, now
! we want to load the system (at 0x10000)


   mov	ax,#SYSSEG	! SYSSEG   = 0x1000	 system loaded at 0x10000 (65536).
   mov	es,ax		! segment of 0x010000
   call	read_it
   call	kill_motor

! After that we check which root-device to use. If the device is
! defined (！= 0), nothing is done and the given device is used.
! Otherwise, either /dev/PS0 (2,28) or /dev/at0 (2,8), depending
! on the number of sectors that the BIOS reports currently.

   seg cs
   mov	ax,root_dev
   cmp	ax,#0
   jne	root_defined
   seg cs
   mov	bx,sectors
   mov	ax,#0x0208		! /dev/ps0 - 1.2Mb
   cmp	bx,#15
   je	root_defined
   mov	ax,#0x021c		! /dev/PS0 - 1.44Mb
   cmp	bx,#18
   je	root_defined
undef_root:
   jmp undef_root
root_defined:
   seg cs
   mov	root_dev,ax
! after that (everyting loaded), we jump to
! the setup-routine loaded directly after
! the bootblock:

   jmpi	0,SETUPSEG 	! SETUPSEG = 0x9020   setup starts here

含义：
主要功能是，把从硬盘第 6 个扇区开始往后的 240 个扇区，加载到内存 0x10000 处。

图解：

衔接：
上述程序使用jmpi， 还记得吗，jmpi 是一个段间跳转指令，表示跳转到 0x9020:0 处执行。这里是什么内容呢，实际上是/boot/setup.s文件的第一行代码。为什么呢？

且看图解：

上图表明了源代码经过编译后生成的机器指令在操作系统开始阶段在内存中运行的位置。
我们看到0x90200的位置正好是硬盘第二扇区的开始，即/boot/setup.s的开始内容。

这篇关于Linux0.11源码学习（一）的文章就介绍到这儿，希望我们推荐的文章对大家有所帮助，也希望大家多多支持为之网！